219 lines
7.1 KiB
CMake
219 lines
7.1 KiB
CMake
#------------------------------------------------------------------------------
|
|
# CLING - the C++ LLVM-based InterpreterG :)
|
|
#
|
|
# This file is dual-licensed: you can choose to license it under the University
|
|
# of Illinois Open Source License or the GNU Lesser General Public License. See
|
|
# LICENSE.TXT for details.
|
|
#------------------------------------------------------------------------------
|
|
|
|
# If we are not building as a part of LLVM, build Cling as an
|
|
# standalone project, using LLVM as an external library:
|
|
if( CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR )
|
|
project(Cling)
|
|
cmake_minimum_required(VERSION 2.8)
|
|
|
|
set(CLING_PATH_TO_LLVM_SOURCE "" CACHE PATH
|
|
"Path to LLVM source code. Not necessary if using an installed LLVM.")
|
|
set(CLING_PATH_TO_LLVM_BUILD "" CACHE PATH
|
|
"Path to the directory where LLVM was built or installed.")
|
|
|
|
if( CLING_PATH_TO_LLVM_SOURCE )
|
|
if( NOT EXISTS "${CLING_PATH_TO_LLVM_SOURCE}/cmake/config-ix.cmake" )
|
|
message(FATAL_ERROR "Please set CLING_PATH_TO_LLVM_SOURCE to the root directory of LLVM source code.")
|
|
else()
|
|
get_filename_component(LLVM_MAIN_SRC_DIR ${CLING_PATH_TO_LLVM_SOURCE}
|
|
ABSOLUTE)
|
|
list(APPEND CMAKE_MODULE_PATH "${LLVM_MAIN_SRC_DIR}/cmake/modules")
|
|
endif()
|
|
endif()
|
|
|
|
if( NOT EXISTS "${CLING_PATH_TO_LLVM_BUILD}/bin/llvm-tblgen${CMAKE_EXECUTABLE_SUFFIX}" )
|
|
message(FATAL_ERROR "Please set CLING_PATH_TO_LLVM_BUILD to a directory containing a LLVM build.")
|
|
endif()
|
|
|
|
list(APPEND CMAKE_MODULE_PATH "${CLING_PATH_TO_LLVM_BUILD}/share/llvm/cmake")
|
|
|
|
# They are used as destination of target generators.
|
|
set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
|
|
set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
|
|
|
|
get_filename_component(PATH_TO_LLVM_BUILD ${CLING_PATH_TO_LLVM_BUILD}
|
|
ABSOLUTE)
|
|
|
|
include(AddLLVM)
|
|
include("${CLING_PATH_TO_LLVM_BUILD}/share/llvm/cmake/LLVMConfig.cmake")
|
|
include(HandleLLVMOptions)
|
|
|
|
set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
|
|
|
|
set(LLVM_MAIN_INCLUDE_DIR "${LLVM_MAIN_SRC_DIR}/include")
|
|
set(LLVM_BINARY_DIR ${CMAKE_BINARY_DIR})
|
|
|
|
set(CMAKE_INCLUDE_CURRENT_DIR ON)
|
|
include_directories("${PATH_TO_LLVM_BUILD}/include" "${LLVM_MAIN_INCLUDE_DIR}")
|
|
link_directories("${PATH_TO_LLVM_BUILD}/lib")
|
|
|
|
set(LLVM_TABLEGEN_EXE "${PATH_TO_LLVM_BUILD}/bin/llvm-tblgen")
|
|
|
|
set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
|
|
set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib )
|
|
set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib )
|
|
|
|
set( CLING_BUILT_STANDALONE 1 )
|
|
endif()
|
|
|
|
set(C_INCLUDE_DIRS "" CACHE STRING
|
|
"Colon separated list of directories cling will search for headers.")
|
|
|
|
set(CLING_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
|
|
set(CLING_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
|
|
|
|
if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
|
|
message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
|
|
"the makefiles distributed with LLVM. Please create a directory and run cmake "
|
|
"from there, passing the path to this source directory as the last argument. "
|
|
"This process created the file `CMakeCache.txt' and the directory "
|
|
"`CMakeFiles'. Please delete them.")
|
|
endif()
|
|
|
|
# Add appropriate flags for GCC
|
|
if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-common -Woverloaded-virtual -Wcast-qual -fno-strict-aliasing -pedantic -Wno-long-long -Wall -W -Wno-unused-parameter -Wwrite-strings")
|
|
endif ()
|
|
|
|
# The package needs to be compiler without RTTI information
|
|
if(MSVC)
|
|
add_definitions(/GR-)
|
|
else()
|
|
add_definitions(-fno-rtti)
|
|
endif()
|
|
|
|
if (APPLE)
|
|
set(CMAKE_MODULE_LINKER_FLAGS "-Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
|
|
endif ()
|
|
|
|
include(LLVMParseArguments)
|
|
|
|
macro(add_cling_library name)
|
|
cmake_parse_arguments(ARG
|
|
""
|
|
""
|
|
"ADDITIONAL_HEADERS"
|
|
${ARGN})
|
|
set(srcs)
|
|
if(MSVC_IDE OR XCODE)
|
|
# Add public headers
|
|
file(RELATIVE_PATH lib_path
|
|
${CLING_SOURCE_DIR}/lib/
|
|
${CMAKE_CURRENT_SOURCE_DIR}
|
|
)
|
|
if(NOT lib_path MATCHES "^[.][.]")
|
|
file( GLOB_RECURSE headers
|
|
${CLING_SOURCE_DIR}/include/cling/${lib_path}/*.h
|
|
${CLING_SOURCE_DIR}/include/cling/${lib_path}/*.def
|
|
)
|
|
set_source_files_properties(${headers} PROPERTIES HEADER_FILE_ONLY ON)
|
|
|
|
file( GLOB_RECURSE tds
|
|
${CLING_SOURCE_DIR}/include/cling/${lib_path}/*.td
|
|
)
|
|
source_group("TableGen descriptions" FILES ${tds})
|
|
set_source_files_properties(${tds}} PROPERTIES HEADER_FILE_ONLY ON)
|
|
|
|
if(headers OR tds)
|
|
set(srcs ${headers} ${tds})
|
|
endif()
|
|
endif()
|
|
endif(MSVC_IDE OR XCODE)
|
|
if(srcs OR ARG_ADDITIONAL_HEADERS)
|
|
set(srcs
|
|
ADDITIONAL_HEADERS
|
|
${srcs}
|
|
${ARG_ADDITIONAL_HEADERS} # It may contain unparsed unknown args.
|
|
)
|
|
endif()
|
|
llvm_add_library(${name} ${ARG_UNPARSED_ARGUMENTS} ${srcs})
|
|
|
|
if(TARGET ${name})
|
|
target_link_libraries(${name} ${cmake_2_8_12_INTERFACE} ${LLVM_COMMON_LIBS})
|
|
|
|
if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "libcling")
|
|
install(TARGETS ${name}
|
|
LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
|
|
ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX}
|
|
RUNTIME DESTINATION bin)
|
|
endif()
|
|
else()
|
|
# Add empty "phony" target
|
|
add_custom_target(${name})
|
|
endif()
|
|
|
|
set_target_properties(${name} PROPERTIES FOLDER "Cling libraries")
|
|
endmacro(add_cling_library)
|
|
|
|
macro(add_cling_executable name)
|
|
add_llvm_executable( ${name} ${ARGN} )
|
|
set_target_properties(${name} PROPERTIES FOLDER "Cling executables")
|
|
endmacro(add_cling_executable)
|
|
|
|
# this is needed when building Cling as part of ROOT:
|
|
include_directories(BEFORE
|
|
${CMAKE_CURRENT_BINARY_DIR}/../llvm/src/tools/clang/include
|
|
${CMAKE_CURRENT_SOURCE_DIR}/../llvm/src/tools/clang/include
|
|
)
|
|
|
|
# and this when building Cling standalone:
|
|
include_directories(BEFORE
|
|
${CMAKE_CURRENT_BINARY_DIR}/../clang/include
|
|
${CMAKE_CURRENT_SOURCE_DIR}/../clang/include
|
|
)
|
|
|
|
include_directories(BEFORE
|
|
${CMAKE_CURRENT_BINARY_DIR}/include
|
|
${CMAKE_CURRENT_SOURCE_DIR}/include
|
|
)
|
|
|
|
install(DIRECTORY include/
|
|
DESTINATION include
|
|
FILES_MATCHING
|
|
PATTERN "*.def"
|
|
PATTERN "*.h"
|
|
PATTERN ".svn" EXCLUDE
|
|
)
|
|
|
|
install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
|
|
DESTINATION include
|
|
FILES_MATCHING
|
|
PATTERN "CMakeFiles" EXCLUDE
|
|
PATTERN "*.inc"
|
|
)
|
|
|
|
add_definitions( -D_GNU_SOURCE
|
|
-DCLING_INCLUDE_PATHS="${CLING_SOURCE_DIR}/include:${CLING_BINARY_DIR}/include" )
|
|
|
|
# Determine cling's version:
|
|
file (STRINGS "VERSION" CLING_VERSION)
|
|
set(CLING_VERSION ROOT_${CLING_VERSION})
|
|
|
|
add_subdirectory(lib)
|
|
add_subdirectory(tools)
|
|
|
|
# TODO: docs.
|
|
#add_subdirectory(test)
|
|
option(CLING_INCLUDE_TESTS
|
|
"Generate build targets for the Cling unit tests."
|
|
${LLVM_INCLUDE_TESTS})
|
|
|
|
if( CLING_INCLUDE_TESTS )
|
|
add_subdirectory(test)
|
|
endif()
|
|
|
|
# Workaround for MSVS10 to avoid the Dialog Hell
|
|
# FIXME: This could be removed with future version of CMake.
|
|
if( CLING_BUILT_STANDALONE AND MSVC_VERSION EQUAL 1600 )
|
|
set(CLING_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/Cling.sln")
|
|
if( EXISTS "${CLING_SLN_FILENAME}" )
|
|
file(APPEND "${CLING_SLN_FILENAME}" "\n# This should be regenerated!\n")
|
|
endif()
|
|
endif()
|