5516c89d58
The .L-prefixed exception handling symbols of get_user() and put_user()
do get discarded from the symbol table of the final kernel image.
This confuses tools which parse that symbol table and try to map the
chunk of code to a symbol. And, in general, from toolchain perspective,
it is a good practice to have all code belong to a symbol, and the
correct one at that.
( Currently, objdump displays that exception handling chunk as part
of the previous symbol which is a "fallback" of sorts and not
correct. )
While at it, rename them to something more descriptive.
[ bp: Rewrite commit message, rename symbols. ]
Signed-off-by: Nadav Amit <namit@vmware.com>
Signed-off-by: Borislav Petkov (AMD) <bp@alien8.de>
Link: https://lore.kernel.org/r/20230525184244.2311-1-namit@vmware.com
153 lines
3.1 KiB
ArmAsm
153 lines
3.1 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* __put_user functions.
|
|
*
|
|
* (C) Copyright 2005 Linus Torvalds
|
|
* (C) Copyright 2005 Andi Kleen
|
|
* (C) Copyright 2008 Glauber Costa
|
|
*
|
|
* These functions have a non-standard call interface
|
|
* to make them more efficient, especially as they
|
|
* return an error value in addition to the "real"
|
|
* return value.
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <asm/thread_info.h>
|
|
#include <asm/errno.h>
|
|
#include <asm/asm.h>
|
|
#include <asm/smap.h>
|
|
#include <asm/export.h>
|
|
|
|
|
|
/*
|
|
* __put_user_X
|
|
*
|
|
* Inputs: %eax[:%edx] contains the data
|
|
* %ecx contains the address
|
|
*
|
|
* Outputs: %ecx is error code (0 or -EFAULT)
|
|
*
|
|
* Clobbers: %ebx needed for task pointer
|
|
*
|
|
* These functions should not modify any other registers,
|
|
* as they get called from within inline assembly.
|
|
*/
|
|
|
|
.macro check_range size:req
|
|
.if IS_ENABLED(CONFIG_X86_64)
|
|
mov %rcx, %rbx
|
|
sar $63, %rbx
|
|
or %rbx, %rcx
|
|
.else
|
|
cmp $TASK_SIZE_MAX-\size+1, %ecx
|
|
jae .Lbad_put_user
|
|
.endif
|
|
.endm
|
|
|
|
.text
|
|
SYM_FUNC_START(__put_user_1)
|
|
check_range size=1
|
|
ASM_STAC
|
|
1: movb %al,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_1)
|
|
EXPORT_SYMBOL(__put_user_1)
|
|
|
|
SYM_FUNC_START(__put_user_nocheck_1)
|
|
ENDBR
|
|
ASM_STAC
|
|
2: movb %al,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_nocheck_1)
|
|
EXPORT_SYMBOL(__put_user_nocheck_1)
|
|
|
|
SYM_FUNC_START(__put_user_2)
|
|
check_range size=2
|
|
ASM_STAC
|
|
3: movw %ax,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_2)
|
|
EXPORT_SYMBOL(__put_user_2)
|
|
|
|
SYM_FUNC_START(__put_user_nocheck_2)
|
|
ENDBR
|
|
ASM_STAC
|
|
4: movw %ax,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_nocheck_2)
|
|
EXPORT_SYMBOL(__put_user_nocheck_2)
|
|
|
|
SYM_FUNC_START(__put_user_4)
|
|
check_range size=4
|
|
ASM_STAC
|
|
5: movl %eax,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_4)
|
|
EXPORT_SYMBOL(__put_user_4)
|
|
|
|
SYM_FUNC_START(__put_user_nocheck_4)
|
|
ENDBR
|
|
ASM_STAC
|
|
6: movl %eax,(%_ASM_CX)
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_nocheck_4)
|
|
EXPORT_SYMBOL(__put_user_nocheck_4)
|
|
|
|
SYM_FUNC_START(__put_user_8)
|
|
check_range size=8
|
|
ASM_STAC
|
|
7: mov %_ASM_AX,(%_ASM_CX)
|
|
#ifdef CONFIG_X86_32
|
|
8: movl %edx,4(%_ASM_CX)
|
|
#endif
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_8)
|
|
EXPORT_SYMBOL(__put_user_8)
|
|
|
|
SYM_FUNC_START(__put_user_nocheck_8)
|
|
ENDBR
|
|
ASM_STAC
|
|
9: mov %_ASM_AX,(%_ASM_CX)
|
|
#ifdef CONFIG_X86_32
|
|
10: movl %edx,4(%_ASM_CX)
|
|
#endif
|
|
xor %ecx,%ecx
|
|
ASM_CLAC
|
|
RET
|
|
SYM_FUNC_END(__put_user_nocheck_8)
|
|
EXPORT_SYMBOL(__put_user_nocheck_8)
|
|
|
|
SYM_CODE_START_LOCAL(__put_user_handle_exception)
|
|
ASM_CLAC
|
|
.Lbad_put_user:
|
|
movl $-EFAULT,%ecx
|
|
RET
|
|
SYM_CODE_END(__put_user_handle_exception)
|
|
|
|
_ASM_EXTABLE(1b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(2b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(3b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(4b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(5b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(6b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(7b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(9b, __put_user_handle_exception)
|
|
#ifdef CONFIG_X86_32
|
|
_ASM_EXTABLE(8b, __put_user_handle_exception)
|
|
_ASM_EXTABLE(10b, __put_user_handle_exception)
|
|
#endif
|