08d3df8c81
The mach/hardware.h is included in lots of places, and it provides three different things on pxa: - the cpu_is_pxa* macros - an indirect inclusion of mach/addr-map.h - the __REG() and io_pv2() helper macros Split it up into separate <linux/soc/pxa/cpu.h> and mach/pxa-regs.h headers, then change all the files that use mach/hardware.h to include the exact set of those three headers that they actually need, allowing for further more targeted cleanup. linux/soc/pxa/cpu.h can remain permanently exported and is now in a global location along with similar headers. pxa-regs.h and addr-map.h are only used in a very small number of drivers now and can be moved to arch/arm/mach-pxa/ directly when those drivers are to pass the necessary data as resources. Cc: Michael Turquette <mturquette@baylibre.com> Cc: Stephen Boyd <sboyd@kernel.org> Acked-by: Viresh Kumar <viresh.kumar@linaro.org> Acked-by: Dmitry Torokhov <dmitry.torokhov@gmail.com> Cc: Jacek Anaszewski <jacek.anaszewski@gmail.com> Cc: Pavel Machek <pavel@ucw.cz> Acked-by: Ulf Hansson <ulf.hansson@linaro.org> Cc: Dominik Brodowski <linux@dominikbrodowski.net> Acked-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Cc: Greg Kroah-Hartman <gregkh@linuxfoundation.org> Cc: Guenter Roeck <linux@roeck-us.net> Acked-by: Mark Brown <broonie@kernel.org> Cc: linux-clk@vger.kernel.org Cc: linux-pm@vger.kernel.org Cc: linux-input@vger.kernel.org Cc: linux-leds@vger.kernel.org Cc: linux-mmc@vger.kernel.org Cc: linux-mtd@lists.infradead.org Cc: linux-rtc@vger.kernel.org Cc: linux-usb@vger.kernel.org Cc: dri-devel@lists.freedesktop.org Cc: linux-fbdev@vger.kernel.org Cc: linux-watchdog@vger.kernel.org Cc: alsa-devel@alsa-project.org Signed-off-by: Arnd Bergmann <arnd@arndb.de>
114 lines
2.7 KiB
ArmAsm
114 lines
2.7 KiB
ArmAsm
/*
|
|
* PXA27x standby mode
|
|
*
|
|
* Author: David Burrage
|
|
*
|
|
* 2005 (c) MontaVista Software, Inc. This file is licensed under
|
|
* the terms of the GNU General Public License version 2. This program
|
|
* is licensed "as is" without any warranty of any kind, whether express
|
|
* or implied.
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/assembler.h>
|
|
|
|
#include <mach/pxa2xx-regs.h>
|
|
|
|
.text
|
|
|
|
#ifdef CONFIG_PXA27x
|
|
ENTRY(pxa_cpu_standby)
|
|
ldr r0, =PSSR
|
|
mov r1, #(PSSR_PH | PSSR_STS)
|
|
mov r2, #PWRMODE_STANDBY
|
|
mov r3, #UNCACHED_PHYS_0 @ Read mem context in.
|
|
ldr ip, [r3]
|
|
b 1f
|
|
|
|
.align 5
|
|
1: mcr p14, 0, r2, c7, c0, 0 @ put the system into Standby
|
|
str r1, [r0] @ make sure PSSR_PH/STS are clear
|
|
ret lr
|
|
|
|
#endif
|
|
|
|
#ifdef CONFIG_PXA3xx
|
|
|
|
#define PXA3_MDCNFG 0x0000
|
|
#define PXA3_MDCNFG_DMCEN (1 << 30)
|
|
#define PXA3_DDR_HCAL 0x0060
|
|
#define PXA3_DDR_HCAL_HCRNG 0x1f
|
|
#define PXA3_DDR_HCAL_HCPROG (1 << 28)
|
|
#define PXA3_DDR_HCAL_HCEN (1 << 31)
|
|
#define PXA3_DMCIER 0x0070
|
|
#define PXA3_DMCIER_EDLP (1 << 29)
|
|
#define PXA3_DMCISR 0x0078
|
|
#define PXA3_RCOMP 0x0100
|
|
#define PXA3_RCOMP_SWEVAL (1 << 31)
|
|
|
|
ENTRY(pm_enter_standby_start)
|
|
mov r1, #0xf6000000 @ DMEMC_REG_BASE (PXA3_MDCNFG)
|
|
add r1, r1, #0x00100000
|
|
|
|
/*
|
|
* Preload the TLB entry for accessing the dynamic memory
|
|
* controller registers. Note that page table lookups will
|
|
* fail until the dynamic memory controller has been
|
|
* reinitialised - and that includes MMU page table walks.
|
|
* This also means that only the dynamic memory controller
|
|
* can be reliably accessed in the code following standby.
|
|
*/
|
|
ldr r2, [r1] @ Dummy read PXA3_MDCNFG
|
|
|
|
mcr p14, 0, r0, c7, c0, 0
|
|
.rept 8
|
|
nop
|
|
.endr
|
|
|
|
ldr r0, [r1, #PXA3_DDR_HCAL] @ Clear (and wait for) HCEN
|
|
bic r0, r0, #PXA3_DDR_HCAL_HCEN
|
|
str r0, [r1, #PXA3_DDR_HCAL]
|
|
1: ldr r0, [r1, #PXA3_DDR_HCAL]
|
|
tst r0, #PXA3_DDR_HCAL_HCEN
|
|
bne 1b
|
|
|
|
ldr r0, [r1, #PXA3_RCOMP] @ Initiate RCOMP
|
|
orr r0, r0, #PXA3_RCOMP_SWEVAL
|
|
str r0, [r1, #PXA3_RCOMP]
|
|
|
|
mov r0, #~0 @ Clear interrupts
|
|
str r0, [r1, #PXA3_DMCISR]
|
|
|
|
ldr r0, [r1, #PXA3_DMCIER] @ set DMIER[EDLP]
|
|
orr r0, r0, #PXA3_DMCIER_EDLP
|
|
str r0, [r1, #PXA3_DMCIER]
|
|
|
|
ldr r0, [r1, #PXA3_DDR_HCAL] @ clear HCRNG, set HCPROG, HCEN
|
|
bic r0, r0, #PXA3_DDR_HCAL_HCRNG
|
|
orr r0, r0, #PXA3_DDR_HCAL_HCEN | PXA3_DDR_HCAL_HCPROG
|
|
str r0, [r1, #PXA3_DDR_HCAL]
|
|
|
|
1: ldr r0, [r1, #PXA3_DMCISR]
|
|
tst r0, #PXA3_DMCIER_EDLP
|
|
beq 1b
|
|
|
|
ldr r0, [r1, #PXA3_MDCNFG] @ set PXA3_MDCNFG[DMCEN]
|
|
orr r0, r0, #PXA3_MDCNFG_DMCEN
|
|
str r0, [r1, #PXA3_MDCNFG]
|
|
1: ldr r0, [r1, #PXA3_MDCNFG]
|
|
tst r0, #PXA3_MDCNFG_DMCEN
|
|
beq 1b
|
|
|
|
ldr r0, [r1, #PXA3_DDR_HCAL] @ set PXA3_DDR_HCAL[HCRNG]
|
|
orr r0, r0, #2 @ HCRNG
|
|
str r0, [r1, #PXA3_DDR_HCAL]
|
|
|
|
ldr r0, [r1, #PXA3_DMCIER] @ Clear the interrupt
|
|
bic r0, r0, #0x20000000
|
|
str r0, [r1, #PXA3_DMCIER]
|
|
|
|
ret lr
|
|
ENTRY(pm_enter_standby_end)
|
|
|
|
#endif
|