6bda667037
This change simplifies the task of making the decompressor relocatable.
The decompressor's image contains special DMA sections between _sdma and
_edma. This DMA segment is loaded at boot as part of the decompressor and
then simply handed over to the decompressed kernel. The decompressor itself
never uses it in any way. The primary reason for this is the need to keep
the aforementioned DMA segment below 2GB which is required by architecture,
and because the decompressor is always loaded at a fixed low physical
address, it is guaranteed that the DMA region will not cross the 2GB
memory limit. If the DMA region had been placed in the decompressed kernel,
then KASLR would make this guarantee impossible to fulfill or it would
be restricted to the first 2GB of memory address space.
This commit moves all DMA sections between _sdma and _edma from
the decompressor's image to the decompressed kernel's image. The complete
DMA region is placed in the init section of the decompressed kernel and
immediately relocated below 2GB at start-up before it is needed by other
parts of the decompressed kernel. The relocation of the DMA region happens
even if the decompressed kernel is already located below 2GB in order
to keep the first implementation simple. The relocation should not have
any noticeable impact on boot time because the DMA segment is only a couple
of pages.
After relocating the DMA sections, the kernel has to fix all references
which point into it. In order to automate this, place all variables
pointing into the DMA sections in a special .dma.refs section. All such
variables must be defined using the new __dma_ref macro. Only variables
containing addresses within the DMA sections must be placed in the new
.dma.refs section.
Furthermore, move the initialization of control registers from
the decompressor to the decompressed kernel because some control registers
reference tables that must be placed in the DMA data section to
guarantee that their addresses are below 2G. Because the decompressed
kernel relocates the DMA sections at startup, the content of control
registers CR2, CR5 and CR15 must be updated with new addresses after
the relocation. The decompressed kernel initializes all control registers
early at boot and then updates the content of CR2, CR5 and CR15
as soon as the DMA relocation has occurred. This practically reverts
the commit a80313ff91 ("s390/kernel: introduce .dma sections").
Signed-off-by: Alexander Egorenkov <egorenar@linux.ibm.com>
Acked-by: Heiko Carstens <hca@linux.ibm.com>
Signed-off-by: Heiko Carstens <hca@linux.ibm.com>
159 lines
3.1 KiB
ArmAsm
159 lines
3.1 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0 */
|
|
/*
|
|
* Code that needs to run below 2 GB.
|
|
*
|
|
* Copyright IBM Corp. 2019
|
|
*/
|
|
|
|
#include <linux/linkage.h>
|
|
#include <asm/errno.h>
|
|
#include <asm/sigp.h>
|
|
|
|
.section .dma.text,"ax"
|
|
/*
|
|
* Simplified version of expoline thunk. The normal thunks can not be used here,
|
|
* because they might be more than 2 GB away, and not reachable by the relative
|
|
* branch. No comdat, exrl, etc. optimizations used here, because it only
|
|
* affects a few functions that are not performance-relevant.
|
|
*/
|
|
.macro BR_EX_DMA_r14
|
|
larl %r1,0f
|
|
ex 0,0(%r1)
|
|
j .
|
|
0: br %r14
|
|
.endm
|
|
|
|
/*
|
|
* int _diag14_dma(unsigned long rx, unsigned long ry1, unsigned long subcode)
|
|
*/
|
|
ENTRY(_diag14_dma)
|
|
lgr %r1,%r2
|
|
lgr %r2,%r3
|
|
lgr %r3,%r4
|
|
lhi %r5,-EIO
|
|
sam31
|
|
diag %r1,%r2,0x14
|
|
.Ldiag14_ex:
|
|
ipm %r5
|
|
srl %r5,28
|
|
.Ldiag14_fault:
|
|
sam64
|
|
lgfr %r2,%r5
|
|
BR_EX_DMA_r14
|
|
EX_TABLE_DMA(.Ldiag14_ex, .Ldiag14_fault)
|
|
ENDPROC(_diag14_dma)
|
|
|
|
/*
|
|
* int _diag210_dma(struct diag210 *addr)
|
|
*/
|
|
ENTRY(_diag210_dma)
|
|
lgr %r1,%r2
|
|
lhi %r2,-1
|
|
sam31
|
|
diag %r1,%r0,0x210
|
|
.Ldiag210_ex:
|
|
ipm %r2
|
|
srl %r2,28
|
|
.Ldiag210_fault:
|
|
sam64
|
|
lgfr %r2,%r2
|
|
BR_EX_DMA_r14
|
|
EX_TABLE_DMA(.Ldiag210_ex, .Ldiag210_fault)
|
|
ENDPROC(_diag210_dma)
|
|
|
|
/*
|
|
* int _diag26c_dma(void *req, void *resp, enum diag26c_sc subcode)
|
|
*/
|
|
ENTRY(_diag26c_dma)
|
|
lghi %r5,-EOPNOTSUPP
|
|
sam31
|
|
diag %r2,%r4,0x26c
|
|
.Ldiag26c_ex:
|
|
sam64
|
|
lgfr %r2,%r5
|
|
BR_EX_DMA_r14
|
|
EX_TABLE_DMA(.Ldiag26c_ex, .Ldiag26c_ex)
|
|
ENDPROC(_diag26c_dma)
|
|
|
|
/*
|
|
* void _diag0c_dma(struct hypfs_diag0c_entry *entry)
|
|
*/
|
|
ENTRY(_diag0c_dma)
|
|
sam31
|
|
diag %r2,%r2,0x0c
|
|
sam64
|
|
BR_EX_DMA_r14
|
|
ENDPROC(_diag0c_dma)
|
|
|
|
/*
|
|
* void _diag308_reset_dma(void)
|
|
*
|
|
* Calls diag 308 subcode 1 and continues execution
|
|
*/
|
|
ENTRY(_diag308_reset_dma)
|
|
larl %r4,.Lctlregs # Save control registers
|
|
stctg %c0,%c15,0(%r4)
|
|
lg %r2,0(%r4) # Disable lowcore protection
|
|
nilh %r2,0xefff
|
|
larl %r4,.Lctlreg0
|
|
stg %r2,0(%r4)
|
|
lctlg %c0,%c0,0(%r4)
|
|
larl %r4,.Lfpctl # Floating point control register
|
|
stfpc 0(%r4)
|
|
larl %r4,.Lprefix # Save prefix register
|
|
stpx 0(%r4)
|
|
larl %r4,.Lprefix_zero # Set prefix register to 0
|
|
spx 0(%r4)
|
|
larl %r4,.Lcontinue_psw # Save PSW flags
|
|
epsw %r2,%r3
|
|
stm %r2,%r3,0(%r4)
|
|
larl %r4,restart_part2 # Setup restart PSW at absolute 0
|
|
larl %r3,.Lrestart_diag308_psw
|
|
og %r4,0(%r3) # Save PSW
|
|
lghi %r3,0
|
|
sturg %r4,%r3 # Use sturg, because of large pages
|
|
lghi %r1,1
|
|
lghi %r0,0
|
|
diag %r0,%r1,0x308
|
|
restart_part2:
|
|
lhi %r0,0 # Load r0 with zero
|
|
lhi %r1,2 # Use mode 2 = ESAME (dump)
|
|
sigp %r1,%r0,SIGP_SET_ARCHITECTURE # Switch to ESAME mode
|
|
sam64 # Switch to 64 bit addressing mode
|
|
larl %r4,.Lctlregs # Restore control registers
|
|
lctlg %c0,%c15,0(%r4)
|
|
larl %r4,.Lfpctl # Restore floating point ctl register
|
|
lfpc 0(%r4)
|
|
larl %r4,.Lprefix # Restore prefix register
|
|
spx 0(%r4)
|
|
larl %r4,.Lcontinue_psw # Restore PSW flags
|
|
larl %r2,.Lcontinue
|
|
stg %r2,8(%r4)
|
|
lpswe 0(%r4)
|
|
.Lcontinue:
|
|
BR_EX_DMA_r14
|
|
ENDPROC(_diag308_reset_dma)
|
|
|
|
.section .dma.data,"aw",@progbits
|
|
.align 8
|
|
.Lrestart_diag308_psw:
|
|
.long 0x00080000,0x80000000
|
|
|
|
.align 8
|
|
.Lcontinue_psw:
|
|
.quad 0,0
|
|
|
|
.align 8
|
|
.Lctlreg0:
|
|
.quad 0
|
|
.Lctlregs:
|
|
.rept 16
|
|
.quad 0
|
|
.endr
|
|
.Lfpctl:
|
|
.long 0
|
|
.Lprefix:
|
|
.long 0
|
|
.Lprefix_zero:
|
|
.long 0
|