mirror of
https://gitlab.com/libvirt/libvirt.git
synced 2024-12-23 21:34:54 +03:00
98ffd82060
Historically we had two top level XSL files for top level and nested documents which only differ in what they pass for 'href_base' to the main 'page.xsl' file. We can instead pass the variable as argument from the build system so that we have just one XSL file and also allow for more nested document trees in the future. The '404' page is special even with the current XSL way so we add a special case for it. Signed-off-by: Peter Krempa <pkrempa@redhat.com> Reviewed-by: Michal Privoznik <mprivozn@redhat.com>
55 lines
1.3 KiB
Meson
55 lines
1.3 KiB
Meson
docs_go_files = [
|
|
'libvirt',
|
|
'libvirtxml',
|
|
]
|
|
|
|
html_xslt_gen_install_dir = docs_html_dir / 'go'
|
|
html_xslt_gen = []
|
|
|
|
foreach name : docs_go_files
|
|
rst_file = '@0@.rst'.format(name)
|
|
|
|
html_xslt_gen += {
|
|
'name': name,
|
|
'file': docs_rst2html5_gen.process(rst_file),
|
|
'source': 'docs' / 'go' / rst_file,
|
|
'href_base': '../',
|
|
}
|
|
endforeach
|
|
|
|
# keep the XSLT processing code block in sync with docs/meson.build
|
|
|
|
# --- begin of XSLT processing ---
|
|
|
|
foreach data : html_xslt_gen
|
|
html_filename = data['name'] + '.html'
|
|
|
|
html_file = custom_target(
|
|
html_filename,
|
|
input: data.get('file', data['name'] + '.html.in'),
|
|
output: html_filename,
|
|
command: [
|
|
xsltproc_prog,
|
|
'--stringparam', 'pagesrc', data.get('source', ''),
|
|
'--stringparam', 'builddir', meson.build_root(),
|
|
'--stringparam', 'timestamp', docs_timestamp,
|
|
'--stringparam', 'href_base', data.get('href_base', ''),
|
|
'--nonet',
|
|
site_xsl,
|
|
'@INPUT@',
|
|
],
|
|
depends: data.get('depends', []),
|
|
depend_files: [ page_xsl ],
|
|
capture: true,
|
|
install: true,
|
|
install_dir: html_xslt_gen_install_dir,
|
|
)
|
|
|
|
install_web_deps += html_file
|
|
install_web_files += html_file.full_path() + ':' + html_xslt_gen_install_dir
|
|
endforeach
|
|
|
|
html_xslt_gen = []
|
|
|
|
# --- end of XSLT processing ---
|