mirror of
https://github.com/systemd/systemd.git
synced 2024-12-25 01:34:28 +03:00
2c12a402cb
Some zsh completion helpers were not installed, so completion was broken. Add systemd-analyze verify. Make systemctl link complete only unit names.
55 lines
1.9 KiB
Plaintext
55 lines
1.9 KiB
Plaintext
#compdef systemd-analyze
|
|
|
|
_systemd_analyze_set-log-level() {
|
|
local -a _levels
|
|
_levels=(debug info notice warning err crit alert emerg)
|
|
_describe -t level 'logging level' _levels || compadd "$@"
|
|
}
|
|
|
|
_systemd_analyze_verify() {
|
|
_sd_unit_files
|
|
}
|
|
|
|
_systemd_analyze_command(){
|
|
local -a _systemd_analyze_cmds
|
|
# Descriptions taken from systemd-analyze --help.
|
|
_systemd_analyze_cmds=(
|
|
'time:Print time spent in the kernel before reaching userspace'
|
|
'blame:Print list of running units ordered by time to init'
|
|
'critical-chain:Print a tree of the time critical chain of units'
|
|
'plot:Output SVG graphic showing service initialization'
|
|
'dot:Dump dependency graph (in dot(1) format)'
|
|
'dump:Dump server status'
|
|
'set-log-level:Set systemd log threshold'
|
|
'verify:Check unit files for correctness'
|
|
)
|
|
|
|
if (( CURRENT == 1 )); then
|
|
_describe "options" _systemd_analyze_cmds
|
|
else
|
|
local curcontext="$curcontext"
|
|
cmd="${${_systemd_analyze_cmds[(r)$words[1]:*]%%:*}}"
|
|
if (( $#cmd )); then
|
|
if (( $+functions[_systemd_analyze_$cmd] )) && (( CURRENT == 2 )); then
|
|
_systemd_analyze_$cmd
|
|
else
|
|
_message "no more options"
|
|
fi
|
|
else
|
|
_message "unknown systemd-analyze command: $words[1]"
|
|
fi
|
|
fi
|
|
}
|
|
|
|
_arguments \
|
|
{-h,--help}'[Show help text.]' \
|
|
'--system[Operate on system systemd instance.]' \
|
|
'--user[Operate on user systemd instance.]' \
|
|
'--no-pager[Do not user pager.]' \
|
|
'--no-man[Do not check man pages.]' \
|
|
'--order[When generating graph for dot, show only order]' \
|
|
'--require[When generating graph for dot, show only requirement]' \
|
|
{-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
|
|
{-M+,--machine=}'[Operate on local container]:machine' \
|
|
'*::systemd-analyze commands:_systemd_analyze_command'
|