mirror of
https://github.com/systemd/systemd.git
synced 2024-11-05 06:52:22 +03:00
2c201c2140
Using conf.set() with a boolean argument does the right thing: either #ifdef or #undef. This means that conf.set can be used unconditionally. Previously I used '1' as the placeholder value, and that needs to be changed to 'true' for consistency (under meson 1 cannot be used in boolean context). All checks need to be adjusted.
44 lines
1.4 KiB
Meson
44 lines
1.4 KiB
Meson
enable_tmpfiles = conf.get('ENABLE_TMPFILES', false)
|
|
|
|
tmpfiles = [['home.conf', ''],
|
|
['journal-nocow.conf', ''],
|
|
['systemd-nologin.conf', ''],
|
|
['systemd-nspawn.conf', ''],
|
|
['systemd-remote.conf', 'ENABLE_REMOTE'],
|
|
['tmp.conf', ''],
|
|
['var.conf', ''],
|
|
['x11.conf', ''],
|
|
['legacy.conf', 'HAVE_SYSV_COMPAT'],
|
|
]
|
|
|
|
foreach pair : tmpfiles
|
|
if not enable_tmpfiles
|
|
# do nothing
|
|
elif pair[1] == '' or conf.get(pair[1], false)
|
|
install_data(pair[0], install_dir : tmpfilesdir)
|
|
else
|
|
message('Not installing tmpfiles.d/@0@ because @1@ is @2@'
|
|
.format(pair[0], pair[1], conf.get(pair[1], 0)))
|
|
endif
|
|
endforeach
|
|
|
|
m4_files = ['etc.conf',
|
|
'systemd.conf']
|
|
|
|
foreach file : m4_files
|
|
custom_target(
|
|
'tmpfiles.d/' + file,
|
|
input : file + '.m4',
|
|
output: file,
|
|
command : [m4, '-P'] + m4_defines + ['@INPUT@'],
|
|
capture : true,
|
|
install : enable_tmpfiles,
|
|
install_dir : tmpfilesdir)
|
|
endforeach
|
|
|
|
if enable_tmpfiles
|
|
meson.add_install_script(
|
|
'sh', '-c',
|
|
mkdir_p.format(join_paths(sysconfdir, 'tmpfiles.d')))
|
|
endif
|