sin/samba-mirror
1
0
Fork 0
mirror of https://github.com/samba-team/samba.git synced 2025-03-10 12:58:35 +03:00
Code

r19861: Add simple pkg-config replacement.

Browse Source 
(This used to be commit a42220c35673317c637e27d59c1a307bedb711a6)
This commit is contained in:
Jelmer Vernooij 2006-11-23 17:27:04 +00:00 committed by Gerald (Jerry) Carter
parent 8d870db811
commit 1aec9389ed
1 changed files with 130 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

130
source4/script/pkg-config Executable file
View File

@ -0,0 +1,130 @@
#!/usr/bin/perl
# Simple pkg-config implementation in perl
# jelmer@samba.org, November 2006
use strict;
use Getopt::Long;
my @dirs = split(/:/, $ENV{PKG_CONFIG_PATH});
my $opt_help = 0;
my $opt_libs = 0;
my $opt_cflags = 0;
my $opt_static = 0;
my $result = GetOptions (
'help|h|?' => \$opt_help,
'static' => \$opt_static,
'libs' => \$opt_libs,
'cflags' => \$opt_cflags
);
if (not $result) {
exit(1);
}
if ($opt_help) {
print "pkg-config replacement in perl\n";
print "Copyright (C) 2006 Jelmer Vernooij <jelmer\@samba.org>\n";
print "\n";
print " --help Print this help message\n";
print " --static Print flags for static libraries\n";
print " --libs Print linker flags\n";
print " --cflags Print C compiler flags\n";
print "\n";
exit(0);
}
sub find_path($)
{
my $name = shift;
foreach my $dir (@dirs) {
if (-f "$dir/$name-uninstalled.pc") {
return "$dir/$name-uninstalled.pc";
}
}
foreach my $dir (@dirs) {
if (-f "$dir/$name.pc" ) {
return "$dir/$name.pc";
}
}
die("No such package `$name'");
}
sub ReplaceVars($$)
{
my ($expr, $vars) = @_;
$_ = $expr;
while (/(.*)\${([^}]+)}(.*)/) {
$_ = "$1$vars->{$2}$3";
}
return $_;
}
sub Parse($)
{
my $name = shift;
my $path = find_path($name);
my %variables = ();
my %fields = ();
my $lineno = 0;
open(IN, "<$path") or die("Unable to open $path: $!");
foreach (<IN>) {
$lineno+=1;
next if (/^#.*/);
if (/^([A-Za-z.]+): (.*)$/) {
$fields{$1} = ReplaceVars($2, \%variables);
} elsif (/^([A-Za-z_]+)=(.*)$/) {
$variables{$1} = ReplaceVars($2, \%variables);
} elsif (/^[ \t]*$/) {
} else {
warn("$path:$lineno: parse error");
}
}
close(IN);
return \%fields;
}
sub Cflags($)
{
my $name = shift;
my $fields = Parse($name);
my $cflags = $fields->{Cflags};
foreach (split(/[, ]/, $fields->{Requires})) {
$cflags .= " ".Cflags($_);
}
return split(/ /, $cflags);
}
sub Libs($)
{
my $name = shift;
my $fields = Parse($name);
my $libs = $fields->{Libs};
foreach (split(/[, ]/, $fields->{Requires})) {
$libs .= " ".Libs($_);
}
if ($opt_static) {
foreach (split(/[ ,]/, $fields->{"Requires.private"})) {
$libs .= " ".Libs($_);
}
}
return split(/ /, $libs);
}
my @out = ();
foreach my $pkg (@ARGV)
{
push (@out, Libs($pkg)) if ($opt_libs);
push (@out, Cflags($pkg)) if ($opt_cflags);
}
if ($#out >= 0) {
print join(' ', @out) . "\n";
}
exit 0;