mirror of
https://github.com/samba-team/samba.git
synced 2025-01-13 13:18:06 +03:00
11bc6056ea
use shared library versions if they are provided by the system.
This puts talloc and tdb in a similar situation as popt:
the system version is used if provided but if it's not there or if it
is too old, we use our internal version statically.
(This used to be commit 86f88eb7b5)
210 lines
5.5 KiB
Plaintext
210 lines
5.5 KiB
Plaintext
dnl -*- mode: m4-mode -*-
|
|
dnl Process this file with autoconf to produce a configure script.
|
|
|
|
dnl disabled 2.53 requirement - we do work with 2.52 on suse 7.3 for example
|
|
dnl AC_PREREQ(2.53)
|
|
|
|
AC_INIT([samba],[],[samba-technical@samba.org])
|
|
|
|
AC_CONFIG_SRCDIR([include/includes.h])
|
|
AC_CONFIG_HEADER(include/config_tmp.h)
|
|
AC_DEFINE(CONFIG_H_IS_FROM_SAMBA,1,[Marker for samba's config.h])
|
|
|
|
# Configuration rules.
|
|
m4_include(build/m4/env.m4)
|
|
m4_include(lib/replace/samba.m4)
|
|
m4_include(lib/smbreadline/readline.m4)
|
|
m4_include(heimdal_build/config.m4)
|
|
m4_include(lib/util/fault.m4)
|
|
m4_include(lib/util/signal.m4)
|
|
m4_include(lib/util/util.m4)
|
|
m4_include(lib/util/fsusage.m4)
|
|
m4_include(lib/util/xattr.m4)
|
|
m4_include(lib/util/capability.m4)
|
|
m4_include(lib/util/time.m4)
|
|
m4_include(lib/popt/samba.m4)
|
|
m4_include(lib/charset/config.m4)
|
|
m4_include(lib/socket/config.m4)
|
|
m4_include(nsswitch/nsstest.m4)
|
|
|
|
AC_CONFIG_FILES(lib/registry/registry.pc)
|
|
AC_CONFIG_FILES(librpc/dcerpc.pc)
|
|
AC_CONFIG_FILES(librpc/ndr.pc)
|
|
AC_CONFIG_FILES(torture/torture.pc)
|
|
AC_CONFIG_FILES(auth/gensec/gensec.pc)
|
|
AC_CONFIG_FILES(param/samba-config.pc)
|
|
AC_CONFIG_FILES(librpc/dcerpc_samr.pc)
|
|
|
|
SMB_EXT_LIB_FROM_PKGCONFIG(LIBTALLOC, talloc >= 1.1.0,
|
|
[],
|
|
[
|
|
m4_include(lib/talloc/libtalloc.m4)
|
|
SMB_INCLUDE_MK(lib/talloc/config.mk)
|
|
]
|
|
)
|
|
|
|
SMB_EXT_LIB_FROM_PKGCONFIG(LIBTDB, tdb >= 1.1.0,
|
|
[],
|
|
[
|
|
m4_include(lib/tdb/libtdb.m4)
|
|
SMB_INCLUDE_MK(lib/tdb/config.mk)
|
|
]
|
|
)
|
|
|
|
SMB_INCLUDE_MK(lib/tdb/python.mk)
|
|
|
|
SMB_EXT_LIB_FROM_PKGCONFIG(LIBLDB, ldb >= 0.9.1,
|
|
[
|
|
SMB_INCLUDE_MK(lib/ldb/ldb_ildap/config.mk)
|
|
SMB_INCLUDE_MK(lib/ldb/tools/config.mk)
|
|
SMB_SUBSYSTEM(ldb_map, [], [LIBLDB])
|
|
define_ldb_modulesdir=no
|
|
],
|
|
[
|
|
# Here we need to do some tricks
|
|
# with AC_CONFIG_COMMANDS_PRE
|
|
# as that's the deferrs the commands
|
|
# to location after $prefix and $exec_prefix
|
|
# have usefull values and directly before
|
|
# creating config.status.
|
|
#
|
|
# The 'eval eval echo' trick is used to
|
|
# actually get the raw absolute directory
|
|
# path as this is needed in config.h
|
|
define_ldb_modulesdir=yes
|
|
AC_CONFIG_COMMANDS_PRE([
|
|
if test x"$define_ldb_modulesdir" = x"yes";then
|
|
LDB_MODULESDIR=`eval eval echo ${modulesdir}/ldb`
|
|
AC_DEFINE_UNQUOTED(LDB_MODULESDIR, "${LDB_MODULESDIR}" , [ldb Modules directory])
|
|
fi
|
|
])
|
|
m4_include(lib/ldb/sqlite3.m4)
|
|
m4_include(lib/ldb/libldb.m4)
|
|
SMB_INCLUDE_MK(lib/ldb/config.mk)
|
|
AC_CONFIG_FILES(lib/ldb/ldb.pc)
|
|
]
|
|
)
|
|
SMB_INCLUDE_MK(lib/ldb/python.mk)
|
|
|
|
m4_include(lib/tls/config.m4)
|
|
m4_include(lib/events/config.m4)
|
|
|
|
dnl m4_include(auth/kerberos/config.m4)
|
|
m4_include(scripting/python/config.m4)
|
|
m4_include(auth/gensec/config.m4)
|
|
m4_include(smbd/process_model.m4)
|
|
m4_include(ntvfs/posix/config.m4)
|
|
m4_include(ntvfs/unixuid/config.m4)
|
|
m4_include(lib/socket_wrapper/config.m4)
|
|
m4_include(lib/nss_wrapper/config.m4)
|
|
m4_include(auth/config.m4)
|
|
m4_include(kdc/config.m4)
|
|
m4_include(ntvfs/sysdep/config.m4)
|
|
m4_include(lib/appweb/config.m4)
|
|
m4_include(nsswitch/config.m4)
|
|
|
|
#################################################
|
|
# add *_CFLAGS only for the real build
|
|
CFLAGS="${CFLAGS} ${DEVELOPER_CFLAGS}"
|
|
|
|
#################################################
|
|
# final configure stuff
|
|
|
|
AC_MSG_CHECKING([configure summary])
|
|
AC_TRY_RUN([#include "${srcdir-.}/build/tests/summary.c"],
|
|
AC_MSG_RESULT(yes),
|
|
AC_MSG_ERROR([summary failure. Aborting config]); exit 1;,
|
|
AC_MSG_WARN([cannot run when cross-compiling]))
|
|
|
|
LIBS=`echo $LIBS | sed -e 's/ *//g'`
|
|
if test x"$LIBS" != x""; then
|
|
echo "LIBS: $LIBS"
|
|
AC_MSG_WARN([the global \$LIBS variable contains some libraries!])
|
|
AC_MSG_WARN([this should not happen, please report to samba-technical@lists.samba.org!])
|
|
AC_MSG_ERROR([only _EXT macros from aclocal.m4 should be used!])
|
|
fi
|
|
|
|
dnl Remove -L/usr/lib/? from LDFLAGS and LIBS
|
|
LIB_REMOVE_USR_LIB(LDFLAGS)
|
|
LIB_REMOVE_USR_LIB(LIBS)
|
|
|
|
dnl Remove -I/usr/include/? from CFLAGS and CPPFLAGS
|
|
CFLAGS_REMOVE_USR_INCLUDE(CFLAGS)
|
|
CFLAGS_REMOVE_USR_INCLUDE(CPPFLAGS)
|
|
|
|
AC_SUBST(ac_default_prefix)
|
|
|
|
for d in build/smb_build bin include ; do
|
|
test -d ${builddir}/$d || AS_MKDIR_P(${builddir}/$d)
|
|
done
|
|
|
|
echo "configure: creating build/smb_build/config.pm"
|
|
cat >build/smb_build/config.pm<<CEOF
|
|
# config.pm - Autogenerate by configure. DO NOT EDIT!
|
|
|
|
package config;
|
|
require Exporter;
|
|
@ISA = qw(Exporter);
|
|
@EXPORT_OK = qw(%enabled %config);
|
|
use strict;
|
|
|
|
use vars qw(%enabled %config);
|
|
|
|
%config = (AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
|
|
AC_Var => '$AC_Var',])
|
|
);
|
|
|
|
$SMB_INFO_ENABLES
|
|
1;
|
|
CEOF
|
|
|
|
echo "configure: creating config.mk"
|
|
cat >config.mk<<CEOF
|
|
# config.mk - Autogenerated by configure, DO NOT EDIT!
|
|
$SMB_INFO_EXT_LIBS
|
|
$SMB_INFO_SUBSYSTEMS
|
|
$SMB_INFO_LIBRARIES
|
|
CEOF
|
|
|
|
AC_OUTPUT_COMMANDS(
|
|
[
|
|
test "x$ac_abs_srcdir" != "x$ac_abs_builddir" && (
|
|
cd $builddir;
|
|
# NOTE: We *must* use -R so we don't follow symlinks (at least on BSD
|
|
# systems).
|
|
test -d heimdal || cp -R $srcdir/heimdal $builddir/
|
|
test -d heimdal_build || cp -R $srcdir/heimdal_build $builddir/
|
|
test -d build || builddir="$builddir" \
|
|
srcdir="$srcdir" \
|
|
$PERL ${srcdir}/script/buildtree.pl
|
|
)
|
|
|
|
$PERL -I${builddir} -I${builddir}/build \
|
|
-I${srcdir} -I${srcdir}/build \
|
|
${srcdir}/build/smb_build/main.pl || exit $?
|
|
],
|
|
[
|
|
srcdir="$srcdir"
|
|
builddir="$builddir"
|
|
PERL="$PERL"
|
|
|
|
export PERL
|
|
export srcdir
|
|
export builddir
|
|
])
|
|
AC_OUTPUT
|
|
|
|
cmp include/config_tmp.h include/config.h >/dev/null 2>&1
|
|
CMP_RET=$?
|
|
if test $CMP_RET != 0; then
|
|
cp include/config_tmp.h include/config.h
|
|
fi
|
|
|
|
echo "configure: creating mkconfig.mk"
|
|
cat >mkconfig.mk<<CEOF
|
|
# mkconfig.mk - Autogenerated by configure, DO NOT EDIT!
|
|
AC_FOREACH([AC_Var], m4_defn([_AC_SUBST_VARS]), [
|
|
AC_Var = $AC_Var])
|
|
$MAKE_SETTINGS
|
|
CEOF
|