samba-mirror/librpc/idl/eventlog.idl

#include "idl_types.h"

/*
  eventlog interface definition
*/

import "lsa.idl", "security.idl";

[ uuid("82273fdc-e32a-18c3-3f78-827929dc23ea"),
  version(0.0),
  helpstring("Event Logger")
] interface eventlog
{
	typedef [bitmap32bit] bitmap {
		EVENTLOG_SEQUENTIAL_READ = 0x0001,
		EVENTLOG_SEEK_READ       = 0x0002,
		EVENTLOG_FORWARDS_READ   = 0x0004,
		EVENTLOG_BACKWARDS_READ  = 0x0008
	} eventlogReadFlags;

	typedef [public] enum {
		EVENTLOG_SUCCESS          = 0x0000,
		EVENTLOG_ERROR_TYPE       = 0x0001,
		EVENTLOG_WARNING_TYPE     = 0x0002,
		EVENTLOG_INFORMATION_TYPE = 0x0004,
		EVENTLOG_AUDIT_SUCCESS    = 0x0008,
		EVENTLOG_AUDIT_FAILURE    = 0x0010
	} eventlogEventTypes;

	typedef struct {
		uint16 unknown0;
		uint16 unknown1;
	} eventlog_OpenUnknown0;
	
	typedef [flag(NDR_NOALIGN),public] struct {
		uint32 size;
		[charset(DOS),value("eLfL")] uint8 reserved[4];
		uint32 record_number;
		time_t time_generated;
		time_t time_written;
		uint32 event_id;
		eventlogEventTypes event_type;
		[range(0,256)] uint16 num_of_strings;
		uint16 event_category;
		uint16 reserved_flags;
		uint32 closing_record_number;
		uint32 stringoffset;
		[value(ndr_size_dom_sid0(&sid, ndr->flags))] uint32 sid_size;
		uint32 sid_offset;
		uint32 data_length;
		uint32 data_offset;
		nstring source_name;
		nstring computer_name;
		[subcontext(0),subcontext_size(sid_size)] dom_sid0 sid;
		nstring strings[num_of_strings];
		astring raw_data;
		[flag(NDR_ALIGN4)] DATA_BLOB _padding;
		[value(size)] uint32 size2;
	} eventlog_Record;

	/******************/
	/* Function: 0x00 */
	NTSTATUS eventlog_ClearEventLogW(
		[in] policy_handle *handle,
		[in,unique] lsa_String *backupfile
	);

	/******************/
	/* Function: 0x01 */
	[todo] NTSTATUS eventlog_BackupEventLogW();
	
	/******************/
	/* Function: 0x02 */
	NTSTATUS eventlog_CloseEventLog(
		[in,out] policy_handle *handle
	);

	/******************/
	/* Function: 0x03 */
	[todo] NTSTATUS eventlog_DeregisterEventSource();

	/******************/
	/* Function: 0x04 */
	NTSTATUS eventlog_GetNumRecords(
		[in] policy_handle *handle,
		[out,ref] uint32 *number
	);

	/******************/
	/* Function: 0x05 */
	NTSTATUS eventlog_GetOldestRecord(
		[in] policy_handle *handle,
		[out,ref] uint32 *oldest_entry
	);

	/******************/
	/* Function: 0x06 */
	[todo] NTSTATUS eventlog_ChangeNotify();

	/******************/
	/* Function: 0x07 */
	NTSTATUS eventlog_OpenEventLogW(
		[in,unique]	    eventlog_OpenUnknown0 *unknown0,
		[in,ref]    lsa_String *logname,
		[in,ref]    lsa_String *servername,
		[in]	    uint32 major_version,
		[in]	    uint32 minor_version,
		[out]   policy_handle *handle
	);

	/******************/
	/* Function: 0x08 */
	[todo] NTSTATUS eventlog_RegisterEventSourceW();

	/******************/
	/* Function: 0x09 */
	[todo] NTSTATUS eventlog_OpenBackupEventLogW();

	/******************/
	/* Function: 0x0a */
	NTSTATUS eventlog_ReadEventLogW(
		[in] policy_handle *handle,
		[in] eventlogReadFlags flags,
		[in] uint32 offset,
		[in] [range(0,0x7FFFF)] uint32 number_of_bytes,
		[out,ref,size_is(number_of_bytes)] uint8 *data,
		[out,ref] uint32 *sent_size,
		[out,ref] uint32 *real_size
	);

	/*****************/
	/* Function 0x0b */
	NTSTATUS eventlog_ReportEventW(
		[in] policy_handle *handle,
		[in] time_t timestamp,
		[in] eventlogEventTypes event_type,
		[in] uint16 event_category,
		[in] uint32 event_id,
		[in] [range(0,256)] uint16 num_of_strings,
		[in] [range(0,0x3FFFF)] uint32 data_size,
		[in,ref] lsa_String *servername,
		[in,unique] dom_sid *user_sid,
		[in,unique] [size_is(num_of_strings)] lsa_String **strings,
		[in,unique] [size_is(data_size)] uint8 *data,
		[in] uint16 flags,
		[in,out,unique] uint32 *record_number,
		[in,out,unique] time_t *time_written
		);

	/*****************/
	/* Function 0x0c */
	[todo] NTSTATUS eventlog_ClearEventLogA();
	
	/******************/
	/* Function: 0x0d */
	[todo] NTSTATUS eventlog_BackupEventLogA();

	/*****************/
	/* Function 0x0e */
	[todo] NTSTATUS eventlog_OpenEventLogA();

	/*****************/
	/* Function 0x0f */
	[todo] NTSTATUS eventlog_RegisterEventSourceA();

	/*****************/
	/* Function 0x10 */
	[todo] NTSTATUS eventlog_OpenBackupEventLogA();

	/*****************/
	/* Function 0x11 */
	[todo] NTSTATUS eventlog_ReadEventLogA();

	/*****************/
	/* Function 0x12 */
	[todo] NTSTATUS eventlog_ReportEventA();

	/*****************/
	/* Function 0x13 */
	[todo] NTSTATUS eventlog_RegisterClusterSvc();

	/*****************/
	/* Function 0x14 */
	[todo] NTSTATUS eventlog_DeregisterClusterSvc();

	/*****************/
	/* Function 0x15 */
	[todo] NTSTATUS eventlog_WriteClusterEvents();

	/*****************/
	/* Function 0x16 */
	[todo] NTSTATUS eventlog_GetLogIntormation();

	/*****************/
	/* Function 0x17 */
	NTSTATUS eventlog_FlushEventLog(
		[in] policy_handle *handle
	);	
}