samba-mirror/check-var.m4 at ec0035c9b8e0690f3bc21f3de089c39eae660916

mirror of https://github.com/samba-team/samba.git synced 2024-12-25 23:21:54 +03:00

Andrew Bartlett 126b48e5ab r20642: This bit of autoconf causes us pain. Revert back to how we had things

before the last merge.

Andrew Bartlett
(This used to be commit 9e7124cc85)

2007-10-10 14:37:22 -05:00

 dnl $Id: check-var.m4,v 1.12 2005/06/16 18:59:10 lha Exp $
 dnl
 dnl rk_CHECK_VAR(variable, includes)
 AC_DEFUN([rk_CHECK_VAR], [
 AC_MSG_CHECKING(for $1)
 AC_CACHE_VAL(ac_cv_var_$1, [
 m4_ifval([$2],[
 	AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2
 	void * foo(void) { return &$1; }]],[[foo()]])],
 	    [ac_cv_var_$1=yes],[ac_cv_var_$1=no])])
 if test "$ac_cv_var_$1" != yes ; then
 AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern int $1;
 int foo(void) { return $1; }]],[[foo()]])],
 	    [ac_cv_var_$1=yes],[ac_cv_var_$1=no])
 fi
 ])
 ac_foo=`eval echo \\$ac_cv_var_$1`
 AC_MSG_RESULT($ac_foo)
 if test "$ac_foo" = yes; then
 	AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_[]$1), 1,
 		[Define if you have the `]$1[' variable.])
 	m4_ifval([$2], AC_CHECK_DECLS([$1],[],[],[$2]))
 fi
 ])
 AU_DEFUN([AC_CHECK_VAR], [rk_CHECK_VAR([$2], [$1])], [foo])